ANSYS10.0幫助文件中，Relese10.0 documentation for ANSYS 7.13 對壓電雙晶片梁的作動、傳感模式進行了仿真分析。

當作為 作動元件時在極性相反的壓電層的厚度方向施加電場，由于正壓電效應(yīng)，一層收縮另一層伸長，結(jié)果導(dǎo)致雙極性晶片彎曲變形，其端部在Y方向產(chǎn)生位移。本例通過再上表面施加100V的電壓。

根據(jù) Uy = -3(d₃₁)(V)(L)²/8(H)²

端部產(chǎn)生-33um的撓度。 通過ANSYS仿真計算 得到撓度為-32.9 um.

傳感元件時 讓其端度產(chǎn)生1mm的大變形 仿真計算 電極上產(chǎn)生電壓。

通過對例子分析 APDL程序理解消化

/batch,list
/title, Static Analysis of a Piezoelectric Bimorph Beam
/nopr
/com,
/PREP7

! 幾何參數(shù)
!
L=100e-3 ! 長度, m
H=0.5e-3 ! 壓電單層厚度, m
!
! 載荷
!
V=100 ! 電極電壓, Volt
Uy=10.e-3 ! 端部撓度, m
!
! PVDF 材料特性
!
E1=2.0e9 ! 楊氏模量, N/m^2
NU12=0.29 ! 泊松比
G12=0.775e9 ! 剪切模量, N/m^2
d31=2.2e-11 ! 壓電應(yīng)變常數(shù), C/N
d32=0.3e-11
d33=-3.0e-11
ept33=12 ! 介電常數(shù)
!
! 雙壓電晶片梁有限元模型
!
local,11 ! 建立局部坐標系 下部 +Y方向
local,12,,,,,180 #p#分頁標題#e#! 建立局部坐標系 上部 -Y方向
csys,11 ! 激活 局部坐標系11
rect,0,L,-H,0 ! 建立 底層面
rect,0,L, 0,H ! 建立 上層面
aglue,all ! 膠合 上下層
esize,H ! 確定 單元尺寸
!
et,1,PLANE223,1001,,0 ! 選定plane223單元, 1001 壓電狀態(tài)
! 初始形變?yōu)?

tb,ANEL,1,,,1 ! 建立彈性柔順系數(shù)矩陣
tbda,1,1/E1,-NU12/E1,-NU12/E1
tbda,7,1/E1,-NU12/E1
tbda,12,1/E1
tbda,16,1/G12

tb,PIEZ,1,,,1 ! 建立壓電應(yīng)變系數(shù)矩陣
tbda,2,d31
tbda,5,d33
tbda,8,d32

tb,DPER,1,,,1 ! 建立介電應(yīng)力常數(shù)矩陣
tbdata,1,ept33,ept33

tblist,all ! 顯示所有材料特性矩陣

! -------------------------------------------------------------------------
! 選擇另外單元 plane13 及其材料特性的輸入
!
!et,1,PLANE13,7,,2 ! 選用二維壓電單元, 平面應(yīng)力狀態(tài)
!
!mp,EX,1,E1 ! 彈性系數(shù)
!mp,NUXY,1,NU12#p#分頁標題#e#
!mp,GXY,1,G12
!
!tb,PIEZ,1 ! 壓電應(yīng)力常數(shù)矩陣
!tbda,2,0.2876e-1
!tbda,5,-0.5186e-1
!tbda,8,-0.7014e-3
!
!mp,PERX,1,11.75 ! 介電應(yīng)變常數(shù)矩陣
! -------------------------------------------------------------------------
type,1 $ esys,11
amesh,1 ! 劃分下層網(wǎng)格
type,1 $ esys,12
amesh,3 ! 劃分上層網(wǎng)格
!
nsel,s,loc,x,L
*get,ntip,node,0,num,min ! 獲得梁端部 控制點坐標 (頂端最下方點)
!
nelec = 10 ! 上部電極個數(shù)
*dim,ntop,array,nelec
l1 = 0 ! 電極初始位置
l2 = L/nelec
*do,i,1,nelec ! 定義上層面電極
nsel,s,loc,y,H
nsel,r,loc,x,l1,l2
cp,i,volt,all !定義處于電極上所有點耦合自由度
*get,ntop(i),node,0,num,min !獲得的電極 上控制節(jié)點 號
l1 = l2 + H/10 !更新電極位置
l2 = l2 + L/nelec
*enddo
nsel,s,loc,y,-H ! 定義下層電極
d,all,volt,0 #p#分頁標題#e#! 底部電極 電壓為零
nsel,s,loc,x,0 ! 限制 梁的最左端 自由度
d,all,ux,0,,,,uy
nsel,all
fini
/SOLU ! 作動器 仿真
antype,static ! 靜態(tài)分析
*do,i,1,nelec
d,ntop(i),volt,V ! 對上方電極進行加壓
*enddo
solve
Uy_an = -3*d31*V*L**2/(8*H**2) ! 理論解
/com,
/com, Actuator mode results:
/com, - Calculated tip displacement Uy = %uy(ntip)% (m)
/com, - Theoretical solution Uy = %Uy_an% (m)
fini
/SOLU ! 傳感 仿真
antype,static,new
*do,i,1,nelec
ddele,ntop(i),volt ! 刪除所加的電極 電壓
*enddo
d,ntip,uy,Uy ! 在梁的端部作用位移
nlgeom,on ! 打開 大應(yīng)變 效果
nsubs,2 ! Set number of substeps
cnvtol,F,1.e-3,1.e-3 ! 設(shè)置 F得 收斂值
cnvtol,CHRG,1.e-8,1.e-3 ! 設(shè)置 電荷 收斂值
!cnvtol,AMPS,1.e-8,1.e-3 !如選擇 plane13單元 設(shè)置參數(shù)AMPS
solve
fini
/POST1
/com,
/com, Sensor mode results:
*do,i,1,nelec
/com, - Electrode %i% Voltage = %volt(ntop(i))% (Volt)
*enddo
/com,
/view,,1,,1 ! 設(shè)置 觀察方位
/dscale,1,1 ! 設(shè)置 刻度
pldisp,1 #p#分頁標題#e#! 顯示 變形前后 的形狀
path,position,2,,100 ! 設(shè)置 路徑 名稱及參數(shù)設(shè)置
ppath,1,,0,H ! 定義路徑 沿著晶片 的上邊沿
ppath,2,,L,H
pdef,Volt,volt,,noav ! 在定義路徑上映射電壓數(shù)據(jù)
pdef,Uy,u,y ! 在定義路徑上映射y方向的位移數(shù)據(jù)
/axlab,x, Position (m) ! 設(shè)置 X軸 標簽 為Position (m)
/axlab,y, Electrode Voltage (Volt)!設(shè)置 Y軸 標簽為 Electrode Voltage (Volt)
plpath,Volt ! 顯示路徑上 電壓
/axlab,y, Beam Deflection (m)
plpath,Uy ! 顯示路徑上的變形
pasave
fini