1.結構靜力分析－－梁分析
/PREP7 !進入前處理器
ET,1,BEAM3 !定義單元類型
R,1,0.25,0.0052,0.5　　!定義實常數
MP,EX,1,210E6
MP,PRXY,1,0.3　　　　　!定義材料屬性
N,1,0
N,2,1
N,3,5
N,4,7
N,5,7
N,6,9
N,7,11
N,8,11
N,9,13
N,10,14　　　　　　　　!定義節點
E,1,2
E,2,3
E,3,4
E,5,6
E,6,7
E,8,9
E,9,10　　　　　　　　 !生成單元
CP,1,UX,4,5
CP,2,UY,4,5
CP,3,UX,7,8
CP,4,UY,7,8　　　　　　!耦合節點
FINISH
/SOLU　　　　　　　　　!進入求解器
D,2,UX
D,2,UY
D,3,UY
D,6,UY
D,9,UY　　　　　　　　 !施加位移約束
F,10,FY,-4　　　　　　　!施加集中約束
SFBEAM,1,1,PRES,4,4
SFBEAM,2,1,PRES,4,4　　　!施加均布力
SOLVE　　　　　　　　　!求解
/POST1　　　　　　　　　!進入后處理器
PLDISP　　　　　　　　　!繪制結構變形圖
PRDISP　　　　　　　　　!列出各節點的位移
ETABLE,IMOMENT,SMISC,6
ETABLE,JMOMENT,SMISC,12
ETABLE,ISHEAR,SMISC,2
ETABLE,JSHEAR,SMISC,8　　　!將節點彎矩、剪力制表
PRETAB　　　　　　　　　　　!列表顯示單元的彎矩、剪力
/TITLE,SHEAR FORCE DISTRIBUTION　　　　　!設置剪力分布圖的標題
PLLS,ISHEAR,JSHEAR　　　　　　　　　　　　!繪制剪力分布圖
/TITLE,BENDING MOMENT IDSTRIBUTION　　　　!設置彎矩分布圖的標題
PLLS,IMOMENT,JMOMENT　　　　　　　　　　　!繪制彎矩分布圖

流固耦合實例

RAD=0.8 !底面半徑
H=1
G=9.8
OMEGAR=2
ROU=1000　　　!定義參數變量
/PREP7　　　　!進入前處理器
ET,1,FLUID79 !選擇單元類型
KEYOPT,1,3,1　　!設置單元關鍵字
MP,EX,1,2E9　　　　!設置楊氏模量
MP,DENS,1,ROU　　　　!設置材料密度
K,1
K,2,RAD
K,3,RAD,H
K,4,,H　　　　　　　!生成關鍵點
A,1,2,3,4　　　　　　!連接關鍵點生成面積
LESIZE,ALL,,,10　　　!設置網格劃分精度
AMESH,ALL　　　　!將面積劃分網絡
/SOLU　　　　　　!進入求解器
DL,2,,UX
DL,1,,UY
NSEL,S,LOC,X
DSYM,SYMM,X
D,ALL,UX
NSEL,ALL　　　　!施加位移約束
ACEL,,G
OMEGA,,OMEGAR　　　!施加慣性力
SOLVE　　　　　　　　!求解
/POST1
SET,LAST　　　　　　!進入通用后處理器
PLNSOL,U,X,0,1　　　!繪制應力云圖
UCENT=UY(22)
UEDGE=UY(12)
UELEV=UEDGE-UCENT　!提取節點位移
結構靜力分析－－殼結構內力分析

LENGTH=100
YOUNG=200000
THICKNESS=2
FORCE=1000
DENSITY=9E-6 !將材質、載荷、板的幾何尺寸等參數化
/PREP7　　　　　!進入前處理器
MP,EX,1,YOUNG
MP,NUXY,1,0.3
MP,DENS,1,DENSITY　　　!定義材質
ET,1,SHELL63　　　　　!定義單元類型
R,1,THICKNESS,THICKNESS,THICKNESS,THICKNESS　　!定義實常數
!構建結構的幾何模型
K,1,0,0
K,2,LENGTH,0
K,3,LENGTH,LENGTH
K,4,0,LENGTH　　　!定義關鍵點
A,1,2,3,4　　　　!通過關鍵點生成面
LSEL,ALL
LESIZE,ALL,,,16
AMESH,ALL　　　　　!設定網格劃分參數，劃分網格
FINISH
/SOLU　　　　!進入求解器
NSEL,S,LOC,X,0,0
D,ALL,ALL,0　　　　　!選擇X＝0的節點將其固定
NSEL,S,LOC,X,LENGTH,LENGTH
D,ALL,ALL,0　　　　　!選擇X＝LENGTH的節點將其固定
NSEL,S,LOC,X,0.5*LENGTH,0.5*LENGTH
NSEL,R,LOC,Y,0.5*LENGTH,0.5*LENGTH
F,ALL,FZ,FORCE
ALLSEL　　　　　　　　!捕捉板的中心點并在中心點處施加集中力荷載
SOLVE　　　!求解
FINISH
/POST1　　　!進入后處理器
/DSC,,10
PLNSOL,U,Z,0,1 !繪圖顯示板的豎向變形
NSEL,ALL　　　　　!提取板的最大豎向變形
NSORT,U,Z,1,1　　　!將節點的位移絕對值以升序排序
*GET,MAXDEFLECTION,SORT,0,MAX　　!提取位移最大值并賦給變量#p#分頁標題#e#
NSEL,S,LOC,X,0
NSEL,A,LOC,X,LENGTH,LENGTH　　　!選擇固定邊節點
NSORT,S,EQV,1,1 　　　　　　　!將節點等效應力的絕對值以升序排序
*GET,MAXSTRESS,SORT,0,MAX　　　!提取等效應力最大值并賦給變量
結構靜力分析－－平面桁架分析

/PREP7 !進入前處理器
ET,1,LINK1　　　!選擇單元
R,1,0.1　　　!定義實常數
MP,EX,1,30E6
MP,PRXY,1,0.3　　　!定義材料屬性
N,1,0
N,2,4
N,3,8
N,4,12
N,5,0,3
N,6,4,3
N,7,8,3　　　　　　!生成節點
E,1,2
E,2,3
E,3,4
E,4,7
E,3,7
E,2,7
E,2,6
E,2,5
E,1,5
E,5,6
E,6,7　　　　　　!生成單元
FINISH
/SOLU　　　　　!進入求解器
D,1,UX
D,1,UY
D,5,UX　　　　　!實加位移約束
F,2,FY,-15
F,3,FY,-15
F,4,FY,-15　　　　　!施加集中力
SOLVE　　　　　　!求解
/POST1　　　　　!進入能用后處理器
PRESOL,FORC　　　　!列表顯示反力