本文介紹了水輪機導(dǎo)葉的ANSYS APDL命令流靜力分析實例。

　　!**************************************

　　! S E T B A S E P A R

　　!**************************************

　　! 軸瓦全部位置約束

　　!**************************************

　　! 導(dǎo)葉參數(shù)

　　!**************************************

　　*SET,H_MAX,185.85 !升壓水頭(M)

　　*SET,BLADE_NUM,20 !導(dǎo)葉NUMBER

　　*SET,RAD_C,6175/2 !導(dǎo)葉分布節(jié)圓

　　!*SET,RAD_B,171.4/2 !導(dǎo)葉基圓

　　*SET,BLADE_H,1106 !掰體高度

　　*SET,TH_SMALL,7.172 !掰體真實位置所與分布節(jié)圓半徑夾角

　　!**************************************

　　*SET,CX_1,-908.2137 !迎水側(cè)厚部分圓心距離導(dǎo)葉基圓距離X坐標(biāo)

　　*SET,CY_1,51.98 !迎水側(cè)厚部分圓心距離導(dǎo)葉基圓距離Y坐標(biāo)

　　*SET,THS_1,356.7-360 !迎水側(cè)厚部分起角度

　　*SET,THE_1,THS_1+31.1!迎水側(cè)厚部分終角度

　　*SET,RC_1,995.4 !迎水側(cè)厚部分圓半徑

　　!**************************************

　　!*SET,CX_2,-2714.274 !迎水側(cè)薄部分圓心距離導(dǎo)葉基圓距離X坐標(biāo)

　　!*SET,CY_2,138.395 !迎水側(cè)薄部分圓心距離導(dǎo)葉基圓距離Y坐標(biāo)

　　*SET,RC_2,2803.5 !迎水側(cè)薄部分圓半徑

　　!**************************************

　　*SET,CX_3,4643.996 !逆水側(cè)厚部分圓心距離導(dǎo)葉基圓距離X坐標(biāo)

　　*SET,CY_3,423.101 !逆水側(cè)厚部分圓心距離導(dǎo)葉基圓距離Y坐標(biāo)

　　*SET,THS_3,179.1 !迎水側(cè)厚部分起角度

　　*SET,THE_3,THS_3+6.1 !迎水側(cè)厚部分終角度

　　*SET,RC_3,4748.9 !逆水側(cè)厚部分圓半徑

　　!**************************************

　　!*SET,CX_4,-64 !上大圓距離導(dǎo)葉基圓距離X坐標(biāo)

　　!*SET,CY_4,498.7 !上大圓距離導(dǎo)葉基圓距離Y坐標(biāo)

　　*SET,RC_4,40.3 !上大圓圓半徑

　　!**************************************

　　*SET,CX_5,0 !下小圓距離導(dǎo)葉基圓距離X坐標(biāo)

　　*SET,CY_5,-448.5 !下小圓距離導(dǎo)葉基圓距離Y坐標(biāo)

　　*SET,THS_5,187.6 !下小圓部分起角度

　　*SET,THE_5,THS_5+159.1 !下小圓部分終角度

　　*SET,RC_5,26.5 !下小圓圓半徑

　　!**************************************

　　!**************************************

　　*SET,ST_H1,40 !上小段軸長度

　　*SET,ST_R1,325/2 !上小段軸半徑

　　!**************************************

　　*SET,SD_H1,40 !下小段軸長度

　　*SET,SD_R1,ST_R1 !下小段軸半徑

　　!**************************************

　　*SET,ST_H2,300 !中軸襯長度

　　*SET,ST_R2,270/2 !中軸襯半徑

　　!**************************************

　　*SET,ST_H3,842 !中軸襯與上軸襯之間長度

　　*SET,ST_R3,260/2 !中軸襯與上軸襯之間半徑

　　!**************************************

　　*SET,ST_H4,210 !上軸襯長度

　　*SET,ST_R4,260/2 !上軸襯半徑

　　!**************************************

　　*SET,ST_H5,297 !上軸襯之上長度

　　*SET,ST_R5,260/2 !上軸襯之上半徑

　　!**************************************

　　*SET,SD_H2,210 !下軸襯長度

　　*SET,SD_R2,260/2 !下軸襯半徑

　　!**************************************

　　!****IT**IS**IMPORTANT**FOR**MAPPED****

　　!**************************************

　　ELEM_CEN1=4 !中心短線分段

　　ELEM_CEN2=6 !中心長線分段

　　ELEM_SMALL=1 !最短線分段

　　ELEM_BLADE=16 !掰體高度分段

　　ELEM_ST_H1=1 !上小段軸高度分段

　　ELEM_ST_H2=8 !中軸襯高度分段(ODD)

　　ELEM_ST_H3=16 !中軸襯與上軸襯之間高度分段

　　ELEM_ST_H4=8 !上軸襯高度分段(ODD)

　　ELEM_ST_H5=8 !上軸襯之上高度分段

　　ELEM_SD_H1=1 !下小段軸高度分段

　　ELEM_SD_H2=8 !下軸襯高度分段(ODD)

　　!**************************************

　　!**************************************

　　/PREP7

　　/GRAPHICS,POWER

　　/TITLE,The caculation of Wicket Gate strength for Baishan Hydrulic Turbine

　　!**************************************

　　! material

　　!**************************************

　　/PREP7

　　ET,1,185

　　ET,100,181

　　R,1,10

　　MP,EX,1,2.06E5

　　MP,NUXY,1,0.29

　　MP,DENS,1,7.85E-9 !鋼板材料

　　!**************************************

　　! 創(chuàng)建內(nèi)殼

　　!**************************************

　　WPOFF,RAD_C

　　!CYL4,,,RAD_B

　　CYL4,CX_1,CY_1,RC_1,THS_1,,THE_1

　　!CYL4,CX_2,CY_2,RC_2,-90,,3

　　CYL4,CX_3,CY_3,RC_3,THS_3,,THE_3

　　!CYL4,CX_4,CY_4,RC_4

　　ADELE,ALL

　　LSEL,U,LINE,,1,4,3

　　LDELE,ALL, , ,1

　　ALLS

　　LARC,2,4,5,RC_4,

　　CYL4,CX_5,CY_5,RC_5,THS_5,,THE_5

　　L,5,3

　　LARC,1,6,5,RC_2,

　　ADELE,ALL,,,1

　　LARC,6,3,5,RC_5,

　　!**************************************

　　LCOMB,4,7,0

　　LCOMB,1,8,0

　　LPLO

　　!LCOMB,2,4,0

　　!LCOMB,1,3,0

　　AL,ALL

　　CYL4,,,ST_R1,0,,90

　　CYL4,,,ST_R1,90,,180

　　CYL4,,,ST_R1,180,,270

　　CYL4,,,ST_R1,270,,360

　　CYL4,,,ST_R2,0,,90

　　CYL4,,,ST_R2,90,,180

　　CYL4,,,ST_R2,180,,270

　　CYL4,,,ST_R2,270,,360

　　CYL4,,,ST_R3,0,,90

　　CYL4,,,ST_R3,90,,180

　　CYL4,,,ST_R3,180,,270

　　CYL4,,,ST_R3,270,,360

　　ALLS

　　APTN,ALL

　　!**************************************

　　LESIZE,64,,,ELEM_CEN2,,,,,0

　　LESIZE,69,,,ELEM_CEN2,,,,,0

　　LESIZE,65,,,ELEM_CEN1,,,,,0

　　LESIZE,67,,,ELEM_CEN1,,,,,0

　　!**************************************

　　LESIZE,84,,,ELEM_SMALL,,,,,0

　　LESIZE,85,,,ELEM_SMALL,,,,,0

　　LESIZE,87,,,ELEM_SMALL,,,,,0

　　LESIZE,89,,,ELEM_SMALL,,,,,0

　　!**************************************

　　LCCAT,59,61

　　LCCAT,81,79

　　!**************************************

　　!**************************************

　　! MESING PROCESSING

　　!**************************************

　　TYPE,100

　　MAT,1

　　REAL,1

　　CSWPLA,11,1,1,1,

　　CSYS,11

　　ASEL,S,LOC,X,0,ST_R1

　　MSHAPE,0,2D

　　MSHKEY,1

　　AMESH,ALL

　　ASEL,INVERT

　　AMESH,ALL

　　ALLS

　　LSEL,R,LCCA

　　LDELE,ALL

　　ASEL,S,AREA,,14

　　ASEL,A,AREA,,15

　　ASEL,A,AREA,,16

　　ASEL,A,AREA,,17

　　ASEL,A,AREA,,18

　　ASEL,A,AREA,,19

　　ASEL,A,AREA,,26

　　ASEL,A,AREA,,27

　　ASEL,A,AREA,,30

　　ASEL,A,AREA,,31

　　ASEL,A,AREA,,34

　　ASEL,A,AREA,,35

　　CM,OUT_CEN,AREA

　　ASEL,INVERT

　　!**************************************

　　TYPE, 1

　　EXTOPT,ESIZE,ELEM_BLADE,0,

　　!EXTOPT,ACLEAR,1

　　EXTOPT,ATTR,0,0,0

　　MAT,1

　　REAL,1

　　ESYS,0

　　VEXT,ALL, , ,0,0,-BLADE_H,,,,

　　!**************************************

　　ALLS

　　CMSEL,S,OUT_CEN,AREA

　　AGEN,2,ALL, , , , ,-BLADE_H, ,0

　　ALLS

　　ASEL,S,LOC,Z,0

　　ASEL,R,LOC,X,0,ST_R1

　　EXTOPT,ESIZE,ELEM_ST_H1,0,

　　VEXT,ALL, , ,0,0,ST_H1,,,,

　　!**************************************

　　ALLS

　　ASEL,S,LOC,Z,ST_H1

　　ASEL,R,LOC,X,0,ST_R2

　　EXTOPT,ESIZE,ELEM_ST_H2,0,

　　VEXT,ALL, , ,0,0,ST_H2,,,,

　　!**************************************

　　ALLS

　　ASEL,S,LOC,Z,ST_H1+ST_H2

　　ASEL,R,LOC,X,0,ST_R3-10

　　EXTOPT,ESIZE,ELEM_ST_H3,0,

　　VEXT,ALL, , ,0,0,ST_H3,,,,

　　!**************************************

　　ALLS

　　ASEL,S,LOC,Z,ST_H1+ST_H2+ST_H3

　　ASEL,R,LOC,X,0,ST_R4-10

　　EXTOPT,ESIZE,ELEM_ST_H4,0,

　　VEXT,ALL, , ,0,0,ST_H4,,,,

　　!**************************************

　　ALLS

　　ASEL,S,LOC,Z,ST_H1+ST_H2+ST_H3+ST_H4

　　ASEL,R,LOC,X,0,ST_R5-10

　　EXTOPT,ESIZE,ELEM_ST_H5,0,

　　VEXT,ALL, , ,0,0,ST_H5,,,,

　　!**************************************

　　ALLS

　　ASEL,S,LOC,Z,-BLADE_H

　　ASEL,R,LOC,X,0,ST_R1

　　EXTOPT,ESIZE,ELEM_SD_H1,0,

　　VEXT,ALL, , ,0,0,-SD_H1,,,,

　　!**************************************

　　ALLS

　　ASEL,S,LOC,Z,-BLADE_H-SD_H1

　　ASEL,R,LOC,X,0,SD_R2

　　EXTOPT,ESIZE,ELEM_SD_H2,0,

　　VEXT,ALL, , ,0,0,-SD_H2,,,,

　　!**************************************

　　ALLS

　　VGEN, ,ALL, , , ,-TH_SMALL, , , ,1

　　ESEL,S,ENAME,,181

　　ASLE

　　ACLEAR,ALL

　　ALLS

　　NUMMRG,KP

　　NUMMRG,NODE

　　NUMMRG,KP

　　!**************************************

　　NSEL,S,LOC,Z,ST_H1+0.01,ST_H1+ST_H2

　　NSEL,R,LOC,X,ST_R2

　　CM,SHAFT_MID,NODE

　　ALLS

　　NSEL,S,LOC,Z,ST_H1+ST_H2+ST_H3,ST_H1+ST_H2+ST_H3+ST_H4

　　NSEL,R,LOC,X,ST_R4

　　CM,SHAFT_TOP,NODE

　　ALLS

　　NSEL,S,LOC,Z,-BLADE_H-SD_H1-0.01,-BLADE_H-SD_H1-SD_H2

　　NSEL,R,LOC,X,ST_R2

　　CM,SHAFT_BOT,NODE

　　ALLS

　　CMGRP,SHAFT_TAO,SHAFT_BOT,SHAFT_MID,SHAFT_TOP

　　CMSEL,S,SHAFT_TAO,NODE

　　CSYS,11

　　NROTAT,ALL

　　ALLS

　　NSEL,S,LOC,Z,ST_H1+ST_H2+ST_H3+ST_H4+ST_H5

　　!NSEL,S,LOC,Z,ST_H1+ST_H2+ST_H3+ST_H4,ST_H1+ST_H2+ST_H3+ST_H4+ST_H5

　　CM,SHAFT_TTOP,NODE

　　CSYS,1

　　NROTAT,ALL

　　!**************************************

　　!***********SOLUTION**LOAD*************

　　!**************************************

　　/SOLU

　　ALLS

　　CMSEL,S,SHAFT_TAO,NODE

　　CSYS,11

　　D,ALL,UX

　　!**************************************

　　ALLS

　　CMSEL,S,SHAFT_TTOP,NODE

　　CSYS,1

　　!D,ALL,ALL

　　D,ALL,UY

　　!**************************************

　　CSYS,11

　　ALLS

　　NSEL,S,LOC,Z,-BLADE_H-SD_H1-SD_H2

　　NSEL,R,LOC,X,-0.1,0.1

　　NSEL,R,LOC,Y,-0.1,0.1D,ALL,UZ

　　!**************************************

　　WPCSYS,-1,0

　　ALLS

　　VSEL,S,LOC,Z,-0.01,-BLADE_H+0.01

　　ASEL,R,EXT

　　ASEL,R,LOC,Z,-0.01,-BLADE_H+0.01

　　ASEL,U, , ,8

　　ASEL,U, , ,43

　　ASEL,U, , ,50

　　ASEL,U, , ,59

　　ASEL,U, , ,65

　　ASEL,U, , ,70

　　ASEL,U, , ,73

　　ASEL,U, , ,77

　　ASEL,U, , ,78

　　/PREP7

　　ASUM,1

　　*GET,P_AREA,AREA,ALL,AREA

　　HMAX_PRE=0.1*3.1415926*(RAD_C*2/10)*H_MAX*(BLADE_H/10)/BLADE_NUM*9.8/P_AREA

　　/SOLU

　　SFA,ALL,1,PRES,HMAX_PRE

　　!**************************************

　　ALLS

　　SBCTRAN

　　SOLV

　　!**************************************

　　/POST1

　　/VIEW, 1 ,1,1,1

　　/ANG, 1

　　/REP,FAST

　　/AUTO, 1

　　/CONT,1,15, , ,

　　/UDOC,1,CNTR,RIGH

　　PLNSOL,S,EQV,0,1

　　!**************************************

　　/RGB,INDEX,100,100,100, 0

　　/RGB,INDEX, 80, 80, 80,13

　　/RGB,INDEX, 60, 60, 60,14

　　/RGB,INDEX, 0, 0, 0,15

　　!**************************************

　　/REPLOT

　　/IMAGE,SAVE,SEQV_NODE,bmp,

　　!/GSAVE,SEQV_NODE,BMP

　　PLESOL,S,EQV,0,1

　　/REPLOT

　　/IMAGE,SAVE,SEQV_ELEM,bmp,

　　!/GSAVE,SEQV_ELEM,BMP

　　PLNSOL,U,SUM,0,1

　　/REPLOT

　　/IMAGE,SAVE,USUM_DMX,bmp,

　　!/GSAVE,USUM_DMX,BMP

　　/EOF

　　!***********************************

　　! E N D

　　!***********************************