一般來說，按“桿梁殼體”單元順序，只要后一種單元的自由度完全包含前一種單元的自由度，則只要有公共節點即可，不需要約束方程，否則需要耦合自由度與約事方程。例如：

　　(1)桿與梁、殼、體單元有公共節點即可，不需要約束方程。

　　(2)梁與殼有公共節點怒可，也不需要約束寫約束方程;殼梁自由度數目相同，自由度也相同，盡管殼的rotz是 虛的自由度，也不妨礙二者之間的關系，這有點類同于梁與桿的關系。

　　(3)梁與體則要在相同位置建立不同的節點 ，然后在節點處耦合自由度與施加約束方程。

　　(4)殼與體則也要相同位置建立不同的節點 ，然后在節點處耦合自由度與施加約束方程。

　　舉例：有一長為100mm的矩形截面梁，截面為10X1mm，與一規格為20mmX7mmX10mm的實體連接，約束實體的端面，在梁端施加大小為3N的y方向的壓力，梁與實體都為一材料 ，彈性模量為30Gpa，泊松比為0.3。本例主要講解梁與實體連接處如何利用耦合及約束方程進行處理。命令流如下：

　　FINI

　　/CLE

　　/FILNAME,BEAM_AND_SOLID_ELEMENTS_CONNECTION !定義工作文件名

　　/TITLE,COUPLE_AND_C*****TRAINT_EQUATION !定義工作名

　　/PREP7

　　ET,1,SOLID95 !定義實體單元類型為SOLID95

　　ET,2,BEAM4 !定義梁單元類型為BEAM4

　　MP,EX,1,3E4 !定義材料的彈性模量

　　MP,PRXY,1,0.3 !定義泊松比

　　R,1 !定義實體單元實常數

　　R,2,10.0,10/12.0,1000/12.0,10.0,1.0 !定義梁單元實常數

　　BLC4,,,20,7,10 !創建矩形塊為實體模型

　　WPOFFS,0,3.5 !將工作平面向Y方向移動3.5

　　WPROTA,0,90 !將工作平面繞X軸旋轉90度

　　VSBW,ALL !將實體沿工作平面剖開

　　WPOFFS,0,5 !將工作平面向Y方向移動5

　　WPROTA,0,90 !將工作平面繞X軸旋轉90度

　　VSBW,ALL !將實體沿工作平面剖開

　　WPCSYS,-1 !將工作平面設為與總體笛卡兒坐標一致

　　K,100,20,3.5,5 !創建關鍵點

　　K,101,120,3.5,5 !創建關鍵點

　　L,100,101 !連接關鍵點生成梁的線實體

　　LSEL,S,LOC,X,21,130 !選擇梁線

　　LATT,1,2,2 !指定梁的單元屬性

　　LESIZE,ALL,,,10 !指定梁上的單元份數

　　LMESH,ALL !劃分梁單元

　　VSEL,ALL !選擇所有實體

　　VATT,1,1,1 !設置實體的單元屬性

　　ESIZE,1 !指定實體單元尺寸

　　MSHAPE,0,2D !設置實體單元為2D

　　MSHKEY,1 !設置為映射網格劃分方法

　　VMESH,ALL !劃分實體單元

　　ALLS !全選

　　FINI !退出前處理

　　!------------------------

　　/SOLU !進入求解器

　　ASEL,S,LOC,X,0 !選擇實體的端面

　　DA,ALL,ALL !約束實體端面

　　ALLS !全選

　　FK,101,FY,-3.0 !在兩端施加Y向壓力

　　CP,1,UX,1,21 !耦合節點1和節點21X方向自由度

　　CP,2,UY,1,21 !耦合節點1和節點21Y方向自由度

　　CP,3,UZ,1,21 !耦合節點1和節點21Z方向自由度

　　CE,1,0,626,UX,1,2328,UX,-1,1,ROTY,-ABS(NZ(626)-NZ(2328)) !設置約束方程

　　CE,2,0,67,UX,1,4283,UX,-1,1,ROTZ,-ABS(NY(67)-NY(4283)) !設置約束方程

　　CE,3,0,67,UZ,1,4283,UZ,-1,1,ROTX,-ABS(NY(67)-NY(4283)) !設置約束方程

　　ALLS !全選

　　SOLVE !保存

　　FINI !退出求解器

　　!------------------------

　　/POST1 !進入通用后處理

　　PLNSOL, U,Y, 0,1.0 !顯示Y方向位移

　　PLNSOL, S,EQV, 0,1.0 !顯示等效應力

　　ETABLE,ZL1,SMISC,1 !讀取梁單元上I節點X方向的力

　　ETABLE,ZL2,SMISC,7 !讀取梁單元上J節點X方向的力

　　ETABLE,MZ1,SMISC,6 !讀取梁單元上I節點Z方向的力矩

　　ETABLE,MZ2,SMISC,12 !讀取梁單元上J節點Z方向的力矩

　　PLETAB,ZL1 !顯示梁單元X方向的力

　　PLETAB,MZ1 !顯示梁單元Z方向力矩

　　!**********************************************