本文介紹了ANSYS中建立混凝土鋼筋模型的相關內容。

　　!一受均布荷載的簡支梁，跨度為3000mm,截面為100x200mm，配有兩根鋼筋，承受的均布載荷為0.04N/mm*mm。命令中采用了1/4模型，材料參數詳見命令中。由于選擇時采用的是實體號而不是坐標，可能在有些系統上會受到影響，各位注意。

　　!鋼筋混凝土簡支梁分析

　　/COM, Structural

　　!----------定義單元及材料等---------------------

　　/PREP7

　　et,1,link8 !定義link8單元

　　et,2,solid65 !定義solid65單元

　　keyopt,2,7,1

　　r,1,314 !定義link8單元的面積

　　r,2 !定義solid65的實常數號

　　mp,ex,1,2e5 !定義link8單元的彈性模量

　　mp,prxy,1,0.3 !定義link8單元的泊松系數

　　mp,ex,2,4e4 !定義solid65單元的彈性模量

　　mp,prxy,2,0.3 !定義solid65單元的泊松系數

　　tb,concr,2 !定義2號為混凝土

　　tbdata,,0.9,1,1.8,50 !定義混凝土的c1,c2,Rl,Ra

　　!----------建立幾何模型-------------------------

　　blc4, , ,50,200,1500 !定義梁體

　　/view,1,1,1,1 !定義ISO查看

　　/ang,1

　　vplot !繪制梁體

　　kwpave,5 !工作平面移動到關鍵點5

　　wpoff,25 !工作平面移動25mm

　　wprot,0,0,90 !工作平面旋轉

　　vsbw,1 !分割梁體

　　wpoff,0,40 !工作平面移動40mm

　　wprot,0,90 !工作平面旋轉

　　vsbw,all !分割梁體

　　wpoff,300 !再將梁體分割為三個區域

　　wprot,0,0,90 !(原為控制單元密度而設)

　　vsbw,all

　　wpoff,0,0,900

　　vsbw,all

　　wpstyl !關閉工作平面顯示

　　nummrg,all !整理編號

　　numcmp,all

　　!------------劃分單元網格---------------------------

　　lsel,s,,,41,57,16 !定義line41,line57為新的選擇集

　　lsel,a,,,9 !定義line9也在選擇集中

　　latt,1,1,1 !定義選擇集的屬性

　　lesize,9,,,20,,,,,1 !將line9劃分為20個單元

　　lesize,41,,,20,,,,,1 !將line41劃分為20個單元

　　lesize,57,,,60,,,,,1 !將line57劃分為60個單元

　　lmesh,all !對線劃分單元

　　!-------------

　　allsel,all !新的選擇集為所有的實體

　　vsel,s,,,all !定義所有體為選擇集

　　vatt,2,2,2 !定義選擇集的屬性

　　lesize,22,,,2,,,,,0 !定義體線的單元數以控制體單元

　　lesize,23,,,2,,,,,0

　　lesize,33,,,2,,,,,0

　　lesize,28,,,4,,,,,0

　　mshape,0,3d !將體劃分單元的形狀定位HEX

　　mshkey,1 !采用MAPPED劃分器

　　vmesh,all !對體進行劃分單元

　　finish

　　!--------------定義約束及荷載-------------------------

　　/solu

　　asel,s,,,2,22,20

　　asel,a,,,14,17,3

　　da,all,uy !對支撐端面施加Uy方向約束

　　asel,s,,,3,23,20

　　asel,a,,,15,19,4

　　da,all,uz !對正對稱面施加Uz方向約束

　　asel,s,,,32,36,4

　　asel,a,,,50,52,2

　　asel,a,,,41,43,2

　　da,all,ux !對側對稱面施加Ux方向約束

　　asel,s,,,21,27,6

　　asel,a,,,42,46,4

　　asel,a,,,35,51,16

　　sfa,all,1,pres,0.04 !對頂面施加面荷載(N/mm*mm)

　　allsel,all

　　!--------------定義非線性分析選項--------------------

　　cnvtol,f,,0.05,2 !定義收斂條件,使用缺省的VALUE

　　nsubst,25 !定義子步數

　　outres,all,all !輸出每一子步的結果

　　autots,1 !打開自動時間步控制

　　lnsrch,1 !打開線性搜索

　　ncnv,2 !如果不收斂時結束而不退出

　　neqit,50 !每一子步中方程的迭代次數限值

　　pred,on !打開預測器

　　time,50 !定義時間

　　solve !求解

　　!--------------進入后處理過程-----------------------

　　finish

　　/post1

　　pldisp,0 !繪制變形圖(缺省為最后一步的)

　　etable,sig,ls,1 !定義應力表

　　plls,sigi,sigi,1 !繪制上述應力

　　plnsol,s,z,0,1 !繪制Z方向的應力

　　/device,vector,on